home *** CD-ROM | disk | FTP | other *** search
/ Whiteline: Alpha / Whiteline Alpha.iso / tex / texte / stw9402 / astrosym / astrosym.uni < prev   
Encoding:
Text File  |  1994-09-22  |  10.9 KB  |  225 lines
  1. % ASTROSYM.UNI : AstroSym (Version 1.00, May 1, 1992) - file 6 of 7
  2. % Peter Schmitt                     eMail: a8131dal@awiuni11.bitnet
  3. % Institute of Mathematics, University of Vienna    Vienna, Austria
  4. %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  5.  
  6. beginchar(O+0,U#,U#,0u#); "Sol";
  7.    D:=U/16;                                       % diameter of central circle
  8.    corners; centers;
  9.    PEN; draw BC..CL..TC..CR..BC..cycle;                   % main circle
  10.    Pen; draw fullcircle scaled D shifted CC;              % central circle
  11.    endchar;
  12.  
  13. beginchar(O+1,46u#,80u#,16u#); "Mercurius";
  14.    corners; centers;
  15.    VV := (CC-CL) rotated 90;
  16.    bC:=CC-VV;
  17.    tC:=CC+2VV+vP/3;
  18.    D:=length(CR-CL);                              % circles: diameter
  19.    s:=length(TC-tC); a:= angle(s,(D/2)+-+s);      % upper partial sector: angle
  20.    SPEN; cross (bC,BC, 3/2,-2P);                           % bottom cross
  21.    PEN;
  22.    draw fullcircle scaled D shifted CC;                  % central circle
  23.    draw halfcircle scaled D rotated  (90+a) shifted tC;  % upper partial circle
  24.    draw halfcircle scaled D rotated -(90+a) shifted tC;
  25.    endchar;
  26.  
  27. beginchar(O+5,44u#,70u#,0u#); "Iuppiter";
  28.    corners; Centers (3/4,1/5); Top (4/5);
  29.    PEN; draw tC--BC;                                    % right vertical bar
  30.         draw CL--CR;                                    % horizontal bar
  31.         draw CL{tC-CL}..{TL-CC}TL;                      % left vertical arc
  32.    endchar;
  33.  
  34. beginchar(O+6,44u#,72u#,12u#); "Saturnus";
  35.    Corners (P,P,d+P,P);;
  36.    Centers (1/6,5/9);                       % BC and TC : left vertical bar
  37.    RT (1/2,1);                              % bR        : right arc (right)
  38.    HOR (0,1/3); Top (6/7);                  % tl and tr : upper horizontal bar
  39.    BOT (2/3,7/9); Bl:=Bl-vd;                % Bl
  40.    Br:=Br-(0,d);                            % Br
  41.    SPEN; draw tl--tr; draw BC--TC;                            % left cross
  42.     PEN; draw CC{dir 20}..{down}bR..{dir250}Bl..{dir-70}Br;   % right arc
  43.    endchar;
  44.  
  45. beginchar(O+10,10/11U#,U#,0u#); "Luna";
  46.   corners; Centers(4/11,1/2);
  47.   VV:=(TL-BL)/2; HH:=VV rotated -90;
  48.   BC:=BL+HH; TC:=TL+HH; % CL=BL+VV;
  49.   R:=length(HH); D:=length(BR-BL);
  50.   t:=(R+-+(D-R))/2R;
  51.   RT (1/2-t,1/2+t);
  52.   PEN; draw tR..TC..CL..BC..bR;                  % big circle
  53.        draw tR..CC..bR;                          % small circle
  54.   endchar;
  55.  
  56. beginchar(O+11,1U#,72u#,0u#); "Aries";
  57.    corners;
  58.    BOT (1/2,1/2);                                % Bl = Br : lower middle point
  59.    TOP (1/6,5/6);                  % (temporary) Tl and Tr : upper arcs (tops) 
  60.    HH:= Tl-TL; VV:= HH rotated -90;
  61.    tr:=Tr+VV;                            % tr : right upper halfcircle (centre)
  62.    D:=length(tr-br); R:=length(HH); s:=D+-+R;   % calculating direction of bar
  63.    b:=angle(s,R); b:=b+angle(tr-br);
  64.    Tr:=tr+(HH rotated (b+90));           % Tr :          (left endpoint)
  65.    tR:=tr+(HH rotated (b-90));           % tR :          (right endpoint)
  66.    tl:=Tl+VV; a:=180-b;                  % tl : left upper halfcircle (centre)
  67.    Tl:=tl+(HH rotated (a-90));           % Tl :          (right endpoint)
  68.    tL:=tl+(HH rotated (a+90));           % tL :          (left endpoint) 
  69.    PEN; draw Bl--Tl{dir a}..{dir (a-180)}tL;          % left part
  70.         draw Br--Tr{dir b}..{dir (b-180)}tR;          % right part
  71.    endchar;
  72.  
  73. beginchar(O+12,1U#,72u#,8u#); "Taurus";
  74.    corners; Centers(1/2,5/9);      % BC and CC : lower circle (top and bottom)
  75.    HOR (1/8,7/8);                  % Tl and Tr : upper arcs (tops)
  76.    Bot (5/18);                     % bl and br : lower circle (left and right)
  77.    LFT (0,4/5); RT (0,4/5);        % tL and tR : upper arcs (left and right)
  78.    PEN; draw Tl{dir 235}..{down}tL..CC..br..BC..bl..CC..{up}tR..{dir 145}Tr;
  79.    endchar;
  80.  
  81. beginchar(O+13,56u#,72u#,8u#); "Gemini";
  82.    corners;
  83.    HOR (2/7,5/7);
  84.    Top (7/8); Bot (1/8);
  85.    PEN; draw BL..bl..br..BR; draw TL..tl..tr..TR; % bottom and upper arc
  86.         draw tl--bl; draw tr--br;                 % left and right vertical bar
  87.    endchar;
  88. beginchar(O+14,84u#,68u#,0u#); "Cancer";
  89.    corners; centers;
  90.    Cl:=2/7[CL,CR]; RT (0,4/5);
  91.    PEN; draw CL{up}..{down}Cl..{up}CL                   % left circle
  92.                ..{right}(TC-2hP/3)..(tR-4hP/3+vP/2);    % upper arc
  93.    picture upper; upper := currentpicture;              % adding rotated copy
  94.    addto currentpicture also upper rotated 180 shifted 2CC;
  95.    endchar;
  96.  
  97. beginchar(O+15,68u#,80u#,10u#); "Leo";
  98.    Corners(P,P,d+P,P); centers;                          % TC
  99.    HOR (1/6,17/20); Top (3/4);          % tl and tr : main arc (left and right)
  100.    BOT (1/3,2/3); rr:=(Bl-BL)/2;
  101.    bL:=BL+(rr rotated 90); bl:=bL+2rr;       % bL and bl : lower left circle
  102.    Br:=BR-(2d,0);                            % Br and BR : lower right arc
  103.    PEN; draw bl{up}..{down}bL..{up}bl                    % lower left circle
  104.            ..{up}tl..{right}TC..{down}tr                 % main arc
  105.            ..{down}Br..{up}BR;                           % lower right arc
  106.    endchar;
  107. beginchar(O+16,100u#,68u#,10u#); "Virgo";
  108.    Corners (P,P,d+P,P); 
  109.    LFT (0,3/4);                   %        tL : left upper arc (left end)
  110.    HOR (1/3,2/3); Top (3/4);      % tl and tr : upper arcs (endpoints)
  111.    TOP (4/14,4/14+1/3);
  112.    Tl:=Tl-(0,4u); Tr:=Tr-(0,4u);  % Tl and Tr : upper arcs (tops)
  113.    RT (1/5,3/4);                  %        tR : right upper arc (right end)
  114.                                   % bR and tR : right vertical bar (ends)
  115.    TR:=(4/14+2/3)[TL,TR];         %        TR : right upper arc (top)
  116.    bC:=.5[Bl,Br]-(0,d/2);         % bC : lower right stroke (endpoint)
  117.    br:=Br-(0,d);                  % br : middle right bar (lower end)
  118.    Br:=Br+vP;                     % Br : lower right vertical stroke (left)
  119.    BR:=2/3[Br,BR];                % BR : lower right vertical stroke (right)
  120.    PEN; draw TL--BL; draw tl--Bl; draw tr--br; draw tR--bR;    % vertical bars
  121.         draw tL{dir 40}..{right}Tl..{down}tl;               % left upper arc
  122.         draw tl{dir 40}..{right}Tr..{down}tr;               % middle upper arc
  123.         draw tr{dir 40}..{right}TR..{down}tR;               % right upper arc
  124.         draw bR{dir250}..{dir190}BR--Br;     % lower right stroke: right part
  125.         draw Br{left}..{dir 235}bC;          % lower right stroke: left part
  126.    endchar;
  127.  
  128. beginchar(O+17,64u#,56u#,-8u#); "Libra";
  129.    corners;
  130.    Centers (1/2,7/15);                 % CL and CR : upper bars (outer ends)
  131.    TOP (1/4,3/4);
  132.    VV:=(TC-Tl) rotated -90;
  133.      tl:=Tl+VV; tr:=Tr+VV;             % tl and tr : upper arc (left and right)
  134.      R:=length(VV); D:=length(TC-CC);         % calculating intersection of
  135.      t:=(R+-+(D-R))/length(BR-BL);            %    upper arc with upper bars
  136.    HOR (1/2-t,1/2+t); Bot (7/15);             % (bl and cl renamed:)
  137.    Cl:=bl; Cr:=br;                     % Cl and Cr : upper arc (inner ends)
  138. %   Cl:=bl+hP; Cr:=br-hP;                     % Cl and Cr : upper arc (inner ends)
  139.    bL:=CL-vP; bl:=Cl-vP; br:=Cr-vP; bR:=CR-vP; % shift upper bars slightly down
  140.    PEN; draw BL--BR;                               % bottom bar
  141.         draw (CL+vP)--bL--bl--Cl                   % left and right upper bar
  142.            & Cl..{up}tl..{right}TC..{down}tr..Cr   % upper arc
  143.            & Cr--br--bR--(CR+vP);
  144.    endchar;
  145.  
  146. beginchar(O+18,(14/15)*100u#-(13/15)*P#+p#,68u#,10u#); "Scorpio";
  147.    Corners (P,P,d+P,P);
  148.    LFT (0,3/4);                      %        tL : left upper arc (left end)
  149.    HOR (5/14,10/14); Top (3/4);      % tl and tr : upper arcs (endpoints)
  150.    TOP (4/14,9/14);
  151.    Tl:=Tl-(0,4u); Tr:=Tr-(0,4u);     % Tl and Tr : upper arcs (tops)
  152.    RT (1/6,1);                       %        bR : lower right arrow (point)
  153.    br:=1/5[Br,BR]-(0,d);             %        br : lower right arc (bottom)
  154.    BR:=2/3[Br,BR];                   % Br and BR : lower right arc (endpoints)
  155.    PEN; draw TL--BL; draw tl--Bl; draw tr--Br;          % vertical bars
  156.         draw tL{dir 40}..{right}Tl..{down}tl;
  157.         draw tl{dir 40}..{right}Tr..{down}tr;
  158.         draw BR{dir angle(BR-bR)}..{left}br..{up}(Br);
  159.    Pen; arrow (BR,bR, 1, 1/4,1/2); 
  160.    endchar;
  161.  
  162. beginchar(O+19,56u#,80u#,8u#); "Sagittarius";
  163.    corners;
  164.    bl:=(1/5)[BL,TR]; tr:=(4/5)[BL,TR]; 
  165.    VV:=TR-BL; a:=angle(VV);
  166.    HH:= VV/10 rotated 90;
  167.    bL := bl+HH; Bl := bl-HH;
  168.    PEN; draw BL--tr; draw bL--Bl;               % shaft and short bar
  169.    Pen; arrow (tr,TR, 5/6, .3,.5);              % point
  170.    endchar;
  171.  
  172. beginchar(O+20,56u#,1U#,0); "Capricornus";
  173.    corners;                                      % TR: top bar (right end)
  174.    Centers (2/3,2/3);                     % BC and CC: loop (bottom and top)
  175.    HOR (1/3,1); Bot (1/3);                % bl and br: loop (left and right)
  176.    TOP(1/4,1);                                   % Tl: top bar (left end)
  177.    LFT (.45,1);                                  % bL: end of loop
  178.    PEN; draw Tl--TR{dir225}                               % top bar
  179.           ..{down}bl..{right}BC..{up}br..{left}CC..bL;    % lower loop
  180.    endchar;
  181.  
  182. beginchar(O+22,56u#,72u#,8u#); "Pisces";
  183.    corners;
  184.    HOR (1/5,4/5); Top (1/2);
  185.    PEN; draw BL..tl..TL; draw BR..tr..TR;    % left and right arc
  186.         draw tl--tr;                         % vertical bar
  187.    endchar;
  188.  
  189. beginchar(O+23,44u#,72u#,12u#); "Saturnus 2";
  190.    corners; Centers (4/9,8/11);
  191.    HOR (0,8/9); Top (19/22);
  192.    RT (6.3/11,1);                                            % bR
  193.    Bl:=2/9[BL,BR]; Bot(.8/12);                               % Bl, bl
  194.    bC:=1/5[BC,TC];                                           % bC
  195.    SPEN; draw tl--tr; draw CC--TC;                               % upper cross
  196.     PEN; draw CC{right}..{down}bR..bC..{dir250}bl..{dir-70}Bl;   % lower arc
  197.    endchar;
  198.  
  199. beginchar(O+27,76u#,50u#,-22u#); "Aquarius 2";
  200.    corners;
  201.                            % upper strokes:
  202.    Centers (3/5,1/2);      % CL and CC : left stroke (left end, right bottom)
  203.    TOP (1/4,5/6);          % Tl and Tr : left stroke (left top, right end)
  204.                            % Tr and CR : right stoke (left and right end)
  205.    PEN; draw (CL+vP)..{right}Tl..{right}(CC+vP)..{dir20}(Tr-vP/2); %left stroke
  206.         draw Tr..{right}(CR+vP);                                 % right stroke
  207.    picture upper; upper:= currentpicture;
  208.    addto currentpicture also upper shifted (0,-(h+d)/2);
  209.    endchar;
  210.  
  211. beginchar(O+28,78u#,56u#,-9u#); "Aquarius 3";
  212.    Corners(P,P,(h+d)/2+P,P);
  213.                                  % upper stroke : points on central line:
  214.    centers;                                      % CL and CR : ends
  215.    HOR (1/5,3/5); Bot(1/2);                      % bl and br : down crossing
  216.    HOR (2/5,4/5); Top(1/2);                      % tl and tr : up crossing
  217.    PEN;
  218.    draw CL{up}..bl{down}..tl{up}..br{down}..tr{up}..CR{down};
  219.    picture upper; upper:= currentpicture;                      % lower stroke
  220.    addto currentpicture also upper shifted (0,-(h+d)/2);
  221.    endchar;
  222.  
  223. %%%%%%%%%%%%%%%%%%%%%%%%%%%
  224. %%% end of ASTROSYM.UNI %%%
  225.